OPTIONS LINESIZE=88 PAGESIZE=53 NOCENTER NODATE NONUMBER NOFMTERR;
*******************************************************************;
* PROJECT NAME: Learning to Use SAS                                ;
*             PROGRAM NAME     LOCATION     DATE     PROGRAMMER    ;
TITLE1 "Source:LEC21P6.SAS    Disk 1998#1 11/18/98       EJS "     ;
* Description:  Example Womans Health Initiative Data at Baseline  ;
*    1 month, and 2 months                                         ;
*******************************************************************;
LIBNAME new "C:\temp";

  **********************************************;
   *** Read data                                *;
   **********************************************;
DATA base ;
  SET new.lec21d1;

DATA mth1;
  SET new.lec21d2;

DATA mth2;
  SET new.lec21d3;
  ***********************************************;
  *** Concatenate a single data file and list   *;
  ***********************************************;

DATA d2;
  SET base (IN=a)
      mth1 (IN=b)
      mth2 (IN=c);

  IF a THEN DO;
     fat=fat0;
     fup=0;
     age1=age;
     DROP fat0 age;
  END;
  IF b THEN DO;
     fat=fat1;
     DROP fat1;
  END;
  IF c THEN DO;
     fat=fat2;
     DROP fat2;
  END;
  LABEL fat="Percent*Fat*Intake:*FAT";

  ***********************************************;
  *** Add age to each record                    *;
  ***********************************************;
PROC SORT DATA=d2;
  BY id fup;
DATA d3 (DROP=age1);
  SET d2;
  BY id;
  RETAIN age;
  IF FIRST.id THEN age=age1;

  ***********************************************;
  *** List by subject                         ***;
  ***********************************************;

PROC PRINT DATA=d3 SPLIT="*" ;
  ID id;
  VAR fup clinic age  fat;
  TITLE2 "Table 6.1. Subject Follow-up Data on Fat Intake ";


RUN;