OPTIONS LINESIZE=88 PAGESIZE=53 NOCENTER NODATE NONUMBER NOFMTERR;
*******************************************************************;
* PROJECT NAME: Learning to Use SAS                                ;
*             PROGRAM NAME     LOCATION     DATE     PROGRAMMER    ;
TITLE1 "Source:LEC14P13.SAS    Disk 1999#1 11/4/98      EJS "      ;
* Description:                                                     ;
*    An example using INFORMATs in an INPUT statement to read dates;
*******************************************************************;

DATA new1;
 INPUT     @1       id         5.
           @8       chardate  $10.
           @8       c_dat1     MMDDYY8.
           @8       c_dat2     MMDDYY10.
           @8       c_dat3     DATE8.
           @8       c_dat4     DATE10.
                    dbp               ;
  LABEL chardate="Characters/in ASCII/Data/(CHARDATE)"
        c_dat1="Informat/MMDDYY8./C_DAT1"
        c_dat2="Informat/MMDDYY10./C_DAT2"
        c_dat3="Informat/DATE8./C_DAT3"
        c_dat4="Informat/DATE10./C_DAT4"
        dbp="Diastolic/BP/DBP";

CARDS;
10728  1/12/60   92
10729  1 12/60   93
10730  1 12 60   94
10731  1.12.60   95
10732  1*12*60   96
10733  1.12 60   97
10728  01/12/60  98
10734  11260     99
20729  12jan1960 120
20730  12 jan 60 121
20731  jan 01 60 122
20732  12jan 60  123
20733  12 jan60  124
;
PROC PRINT DATA=new1 SPLIT="/";
  ID id chardate;
  VAR  c_dat1-c_dat4 dbp;
  TITLE2 "Table 1. Listing of Dates with INFORMAT in Input Statement";

RUN;